Fractales - Catalogue L-Systems

Koch :

Koch { 
  Angle 6  ; 1/6 tour = 60°
  Axiom F
  F=F+F--F+F
}

Koch flake :

Kochflake { 
  Angle 6  ; 1/6 tour = 60°
  Axiom F--F--F; 3 couleurs : c09F--c02F--c12F
  F=F+F--F+F
}

Peano :

La courbe est ici "arrondie"
pour mettre en évidence le trajet.

Peano2 { 
  Angle 4 ; 90°
  Axiom F
  F=F-F+F+F+F-F-F-F+F
  }

Peanornd { ; arrondie
  Angle 8 ; 90°/2
  Axiom FX
  F=
  ; sur une seule ligne X= :
  X=FX-@.5FZ@2-FX+@.5FZ@2+FX+@.5FZ@2+FX+@.5FZ@2
   +FX-@.5FZ@2-FX-@.5FZ@2-FX-@.5FZ@2-FX+@.5FZ@2+FX
  Z=FZ
  }

Hilbert :

Hilbert {
  Angle 4 ; 90°
  Axiom X
  X=-YF+XFX+FY-
  Y=+XF-YFY-FX+
  }

Triangle de Sierpinsky :

... mais bien d'autres variantes.

Sierpinsky {
  Angle 6 ; 60°
  Axiom +c02FY-c09FX-c12FY+ ; FX
  F=
  X=+FY-FX-FY+
  Y=-FX+FY+FX-
}

Levy :

Levy {
  Angle 8 ; 90°/2
  Axiom F ; 2 couleurs : +c09F--c12F+
  F=+F--F+
}

Heighway :

Là aussi on peut "arrondir"
la courbe pour mettre en
évidence le trajet.

Heighway {
  Angle 4  ; 90°
  Axiom X ; 2 couleurs : c09FX-c12FY
  F=
  X=FX-FY
  Y=FX+FY
}

Dragonrnd { ; version arrondie
  Angle 8 ; 90°/2
  Axiom X ; 2 couleurs : C09FX-@.5FZ@2-C12FY
  F=
  X=FX-@.5FZ@2-FY
  Y=FX+@.5FZ@2+FY
  Z=FZ
  }

Twindragon :

TwinDragon {
  Angle 4
  Axiom c09fx+c12fx
  f=
  x=fx+fy
  y=fx-fy
  }

Terdragon :

Terdragon {
  Angle 3   ; 120°
  Axiom f   ; 3 couleurs : C09f+C12f-C02f
  f=f+f-f
}

Mandelbrot Quintet :

Quintet {
  Angle 4 ; 90°
  Axiom FB; 5 couleurs : c02FB+c09FA-c10FB-Jc12FBc13FA
  F=
  A=FBFA+HFA+FB-FA
  B=FB+FA-FB-JFBFA
  H=-
  J=+
  }

Flowsnake :

FlowSnake {
  Angle=6 ; 60°
  Axiom FL; c09FL-c02FR--c12FR+c10FL++c13FLC11FL+c43FR-
  F=
  L=FL-FR--FR+FL++FLFL+FR-
  R=+FL-FRFR--FR-FL++FL+FR
  }

Triangle 30-60° :

Puis une version "lissée"
mais plus compliquée
à colorier.

Tri3060 { ; triangle 30-60
  Angle 12 ; 30°
  Axiom fy ; tricolore : +++c09fw----c10fzc12fw+
  f=
  y=+++fw----fzfw+
  x=+fzfw----fz+++
  w=---fy++++fxfy-
  z=-fxfy++++fx---
  }

Lace3060 { ; version tricolore
  Angle 12
  ; Axiom sur une seule ligne :
  Axiom c02+++x--F--zFx+++F+++zFx--F--z+++F+++x--F--zFx--F
        c09--zFx--F--z+++F+++x--F--zFx+++F+++zFx--F--zF
        c12x--F--zFx+++F+++zFx--F--z+++F+++x--F--zFx+
  ; monochrome : Axiom w
  w=+++x--F--zFx+
  x=---w++F++yFw-
  y=+zFx--F--z+++
  z=-yFw++F++y---
  }

Pentigree :

Pentigree {
  Angle 10 ; 36°
  Axiom F ; 5 fois : c13F++c09F++c10F++c12F++c11F
  F=+F++F----F--F++F++F- 
}

Pentadendrite :

Pentadendrite {
  Angle 5 ; 72°
  Axiom F ; 5 fois : c13F+c09F+c10F+c12F+c11F
  F=F+F-F--F+F+F
}

Buisson :

Bush { ; Adrian Mariano
  Angle 16
  Axiom ++++F
  F=FF-[-F+F+F]+[+F-F-F]
  }

Rameau :

Weed {
  Angle 50
  Axiom +++++++++++++x
  x=f[@.5+++++++++x]-f[@.4-----------!x]@.6x
  }

On peut aussi réaliser des pavages, pas forcément fractals :
En restant dans le domaine des rep-tiles, la dissection du sphinx :

Sphinx

Sphinx { ; by Herb Savage
  Angle 6
  Axiom X
  X=+FF-YFF+FF--FFF|X|F--YFFFYFFF|
  Y=-FF+XFF-FF++FFF|Y|F++XFFFXFFF|
  F=GG
  G=GG
  }